Change sharpness and brightness of a selected picture

[Peter Kinross]

Would anyone know how to change the sharpness and brightness of a selected picture using Word vba?

[HansV]

For example:

Code: Select all

Sub PictureTest()
    With ActiveDocument.InlineShapes(1)
        With .PictureFormat
            .Brightness = 0.6
            .Contrast = 0.4
        End With
        .Fill.PictureEffects.Insert(msoEffectSharpenSoften).EffectParameters(1).Value = 0.3
    End With
End Sub

[snb]

When already selected:

Code: Select all

Sub M_snb()
  With Selection.ShapeRange.PictureFormat
    .Brightness = 0.5
    .Contrast = 0.5
    .Parent.Fill.PictureEffects.Insert(25).EffectParameters(1).Value = 0.5
  End With
End Sub

[Peter Kinross]

Oh dear, I completely missed your reply Hans - sorry. No idea how that happened.

Code: Select all

Sub PictureTest()
    With ActiveDocument.InlineShapes(1)
        With .PictureFormat
            .Brightness = 0.2
            .Contrast = 0
        End With
        .Fill.PictureEffects.Insert(msoEffectSharpenSoften).EffectParameters(1).Value = 0.75
    End With
End Sub

The above Sub changes Sharpness to 75% - great; Brightness to -60% - not great; Contrast to -100% - not great.

The first line of the Sub M_snb() produces the error "Invalid procedure call"

[Peter Kinross]

Played around and got it working. Why, oh why did I change your values.

Code: Select all

Sub FixPic()
Dim Num As Integer
Num = ActiveDocument.InlineShapes.Count
For x = 1 To Num
    With ActiveDocument.InlineShapes(x)
        With .PictureFormat
            .Brightness = 0.6
        End With
        .Fill.PictureEffects.Insert(msoEffectSharpenSoften).EffectParameters(1).Value = 0.75
    End With
Next    'x
End Sub

ThanksHansStamp.gif