listview and checkbox

[sal21]

i'm on vb 6.0

I need to permit to the user to check only a checkbox,"one by one", and not permit to use a multiselect checkbox, possible?

Similar oprtion button.

[HansV]

Create an event procedure for the ItemCheck event of the listview:

Code: Select all

Private Sub ListView1_ItemCheck(ByVal Item As MSComctlLib.ListItem)
    Static LastChecked As ListItem
    If Item.Checked Then
        If Not LastChecked Is Nothing Then
            LastChecked.Checked = False
        End If
        Set LastChecked = Item
    End If
End Sub

[sal21]

Create an event procedure for the ItemCheck event of the listview:

Code: Select all

Private Sub ListView1_ItemCheck(ByVal Item As MSComctlLib.ListItem)
    Static LastChecked As ListItem
    If Item.Checked Then
        If Not LastChecked Is Nothing Then
            LastChecked.Checked = False
        End If
        Set LastChecked = Item
    End If
End Sub

I have no words!!!!

Work perfect!
Tks bro

[sal21]

Create an event procedure for the ItemCheck event of the listview:

Code: Select all

Private Sub ListView1_ItemCheck(ByVal Item As MSComctlLib.ListItem)
    Static LastChecked As ListItem
    If Item.Checked Then
        If Not LastChecked Is Nothing Then
            LastChecked.Checked = False
        End If
        Set LastChecked = Item
    End If
End Sub

HI BRO, sorry if i replay on old post.

actually i use this code to check un check a checkbox in msflexgrid:

Code: Select all

Private Sub MSFlexGrid1_Click()
    
    With MSFlexGrid1

        If .Col = 0 And .Row >= 1 Then
        
            If .CellPicture = picChecked Then
                Set .CellPicture = picUnchecked
            Else
                Set .CellPicture = picChecked
            End If

        End If

    End With
    
End Sub

possible to have the same condition in msflexgrid...?

In effect i need to maintain in live the last checked cell.

[HansV]

I cannot test - does this work?

Code: Select all

Private Sub MSFlexGrid1_Click()
    Static OldRow As Long, OldCol As Long
    Static NewRow As Long, NewCol As Long
    With MSFlexGrid1
        NewRow = .Row
        NewCol = .Col
        If NewCol = 0 And NewRow >= 1 Then
            If Not .CellPicture = picChecked Then
                Set .CellPicture = picChecked
                If OldCol = 0 And OldRow >= 1 Then
                    .Row = OldRow
                    .Col = OldCol
                    Set .CellPicture = picUnchecked
                    .Row = NewRow
                    .Col = NewCol
                End If
                OldRow = NewRow
                OldCol = NewCol
            End If
        End If
    End With
End Sub

There may be better ways...

[sal21]

I cannot test - does this work?

Code: Select all

Private Sub MSFlexGrid1_Click()
    Static OldRow As Long, OldCol As Long
    Static NewRow As Long, NewCol As Long
    With MSFlexGrid1
        NewRow = .Row
        NewCol = .Col
        If NewCol = 0 And NewRow >= 1 Then
            If Not .CellPicture = picChecked Then
                Set .CellPicture = picChecked
                If OldCol = 0 And OldRow >= 1 Then
                    .Row = OldRow
                    .Col = OldCol
                    Set .CellPicture = picUnchecked
                    .Row = NewRow
                    .Col = NewCol
                End If
                OldRow = NewRow
                OldCol = NewCol
            End If
        End If
    End With
End Sub

There may be better ways...

great! Work!
Tks