Why don't I always get the option for html mail?

jmt356
SilverLounger
Posts: 2187
Joined: 28 Mar 2010, 01:49

Why don't I always get the option for html mail?

Post by jmt356 »

When I'm typing an email in Rich Text format, and I attach a file, I get a big icon placed where my cursor was in the message when I inserted the attachment. I much prefer the HTML and Plain Text feature where dropped in an the image gets placed in an attachment causes a new field below the subject line to appear, and the attachment's name appears in that field. Yet I don't always have the complete freedom between switching between all of the mail formats. For example, in my current format, I can only switch between Plain Text or Rich Text format. I can get to HTML format if I first change the format to Plain Text, but then I lose the italics in my message, and it doesn't come back when I switch from Plain Text to HTML. And doing it this way for some reason causes all of my text to be reduced to 10 pt. rather than to the default 12 pt font.

Is there another way to get HTML format?
Regards,

JMT

User avatar
HansV
Administrator
Posts: 72605
Joined: 16 Jan 2010, 00:14
Status: Microsoft MVP
Location: Wageningen, The Netherlands

Re: Why don't I always get the option for html mail?

Post by HansV »

You cannot convert from Rich Text to HTML in the Outlook interface. You can do it in a macro, though:

Code: Select all

Public Sub ConvertToHTML()
  Dim lngC As Long
  Dim strMsg As String

  On Error GoTo ErrHandler

  If TypeName(ActiveWindow) = "Inspector" Then
    strMsg = "This macro should be run from the main Outlook window."
  ElseIf TypeName(ActiveWindow) = "Explorer" Then
    If ActiveExplorer.CurrentFolder.DefaultItemType = olMailItem Then
      If ActiveExplorer.CurrentFolder.Items.Count > 0 Then
        If ActiveExplorer.Selection.Count > 0 Then
          For lngC = 1 To ActiveExplorer.Selection.Count
            With ActiveExplorer.Selection.Item(lngC)
              If .Class = olMail Then
                If Not .BodyFormat = olFormatHTML Then
                  .BodyFormat = olFormatHTML
                  .Save
                End If
              End If
            End With
          Next lngC
        Else
          strMsg = "You haven't selected any items."
        End If
      Else
        strMsg = "This folder doesn't contain any items."
      End If
    Else
      strMsg = "This macro should be run from an e-mail folder."
    End If
  End If

  If Not strMsg = "" Then
    MsgBox strMsg, vbExclamation
  End If
  Exit Sub

ErrHandler:
  MsgBox Err.Description, vbExclamation
End Sub
This macro is intended to be run from the main Outlook window, not from an opened e-mail. It will attempt to convert all selected items to HTML.
Regards,
Hans

User avatar
StuartR
Administrator
Posts: 11641
Joined: 16 Jan 2010, 15:49
Location: London, Europe

Re: Why don't I always get the option for html mail?

Post by StuartR »

HansV wrote:You cannot convert from Rich Text to HTML in the Outlook interface...
You can convert directly between Rich Text and HTML formats in Outlook 2010, I am travelling and can't check my Office 2007 PC to see if it works there too.
StuartR


User avatar
HansV
Administrator
Posts: 72605
Joined: 16 Jan 2010, 00:14
Status: Microsoft MVP
Location: Wageningen, The Netherlands

Re: Why don't I always get the option for html mail?

Post by HansV »

In Outlook 2007 direct conversion is possible too, but not in Outlook 2003 or before, at least if Word is not the mail editor. I wrote the above macro some time ago for my boss, who wanted to convert all his e-mails to HTML format in Outlook 2003.
Regards,
Hans