Default Setting: Picture Format

jstevens
GoldLounger
Posts: 2617
Joined: 26 Jan 2010, 16:31
Location: Southern California

Default Setting: Picture Format

Post by jstevens »

Is there a default setting to to apply a solid line around a picture?
EL_42.png
You do not have the required permissions to view the files attached to this post.
Regards,
John

User avatar
HansV
Administrator
Posts: 78233
Joined: 16 Jan 2010, 00:14
Status: Microsoft MVP
Location: Wageningen, The Netherlands

Re: Default Setting: Picture Format

Post by HansV »

As far as I know, there isn't.
Best wishes,
Hans

User avatar
Rudi
gamma jay
Posts: 25455
Joined: 17 Mar 2010, 17:33
Location: Cape Town

Re: Default Setting: Picture Format

Post by Rudi »

I use a custom macro to add a border and a shadow around any images I insert into an email.
I have a QAT button added to the new email window that triggers the macro after I have selected the image to format with a border.
I definitely helps to avoid having to constantly and manually add a border and shadow to any image.

Below is the macro I use:
Place it anywhere within the "ThisOutlookSession" module.
Comment out the shadow options if you do not want that.
The p.Line statement contains the weight and forecolor properties to determine the line. Edit these to suit.

Code: Select all

Public Sub FormatPicture()
    Dim p As Object
    If TypeName(ActiveWindow) = "Inspector" Then
        If Not ActiveInspector.CurrentItem.Class = olMail Then
            MsgBox "This item is not an e-mail message.", vbExclamation
            Exit Sub
        End If
    Else
        MsgBox "Please open an e-mail message and select a shape in it.", vbExclamation
        Exit Sub
    End If
    With ActiveInspector.WordEditor.Application
        If .Selection.InlineShapes.Count = 1 Then
            Set p = .Selection.InlineShapes(1)
        ElseIf .Selection.ShapeRange.Count = 1 Then
            Set p = .Selection.ShapeRange(1)
        Else
            MsgBox "Please select a single shape or inline shape.", vbExclamation
            Exit Sub
        End If
    End With
    With p.Shadow
        .Blur = 4
        .OffsetX = 3
        .OffsetY = 3
        .Size = 100
        .Style = msoShadowStyleOuterShadow
        .Transparency = 0.57
        .Visible = True
    End With
    With p.Line
        .Weight = 1
        .ForeColor.RGB = RGB(1, 1, 1) 'vbBlack
    End With
End Sub
Regards,
Rudi

If your absence does not affect them, your presence didn't matter.