Macro to format a picture

[Rudi]

Hi,

I noticed that Word 2010 does not record the actions to add a picture style and border weight to selected pictures. I was wondering if anyone can assist me in creating a macro that does two things:

Assuming the picture is already selected...
1. Assigns the picture style called: Simple frame black
2. Assigns a picture border with a line weight of 1pt to the picture

Thats it. It's weird that this does not get recorded, but any assistance will be greatly appreciated. TX.

[HansV]

Is it an inline picture or a floating picture?

[Rudi]

Both. Most are wrapped around text and some are inline. However, the picture will always be selected before i run the macro.
TX

[HansV]

Try this:

Code: Select all

Sub FormatPicture()
    Dim p As Object
    If Selection.InlineShapes.Count = 1 Then
        Set p = Selection.InlineShapes(1)
    ElseIf Selection.ShapeRange.Count = 1 Then
        Set p = Selection.ShapeRange(1)
    Else
        MsgBox "Please select a single shape or inline shape.", vbExclamation
        Exit Sub
    End If
    With p.Shadow
        .Blur = 4
        .OffsetX = 3
        .OffsetY = 3
        .Size = 100
        .Style = msoShadowStyleOuterShadow
        .Transparency = 0.57
        .Visible = True
    End With
    With p.Line
        .Weight = 1
        .ForeColor = vbBlack
    End With
End Sub

It should work with both inline shapes and floating shapes.

[Rudi]

Awesome. Hans....Thank you for the time and effort. I really do appreciate it.
Big Cheers!!!!