VBA/Macro Word doc to PDF

[JDeMaro22]

Hello,

I was just wondering if there was a VBA/Macro script to run in a workbook that would print or save multiple word documents as pdfs in a specific folder?

Thanks for your time,

Joshua

[HansV]

Try this - it is untested. Replace C:\Word\ with the folder path; keep the \ at the end.

Code: Select all

Sub ExportDocs()
    Const strFolder As String = "C:\Word\"
    Dim strFile As String
    Dim strPDF As String
    Dim lngPos As Long
    Dim objWrd As Object ' Word.Application
    Dim objDoc As Object ' Word.Document
    Dim f As Boolean
    On Error Resume Next
    Set objWrd = GetObject(Class:="Word.Application")
    If objWrd Is Nothing Then
        Set objWrd = CreateObject(Class:="Word.Application")
        f = True
    End If
    On Error GoTo ErrHandler
    strFile = Dir(strFolder & "*.doc*")
    Do While strFile <> ""
        Set objDoc = objWrd.Documents.Open(Filename:=strFolder & strFile)
        lngPos = InStrRev(strFile, ".")
        strPDF = Left(strFile, lngPos) & "pdf"
        objDoc.ExportAsFixedFormat OutputFileName:=strFolder & strPDF, ExportFormat:=17 ' wdExportFormatPDF
        objDoc.Close SaveChanges:=False
        strFile = Dir
    Loop
ExitHandler:
    On Error Resume Next
    If f Then
        objWrd.Quit SaveChanges:=False
    End If
    Exit Sub
ErrHandler:
    MsgBox Err.Description, vbExclamation
    Resume ExitHandler
End Sub

[JDeMaro22]

Wow, it works great.

Thank you Hans

[ChrisGreaves]

...
On Error GoTo ErrHandler
strFile = Dir(strFolder & "*.doc*")
...

Hi Hans.
Just curious.
Why "On Error"?
Is that to trap a file not existing?
If so why not test with a procedure blnFileExists and report the (false) results of that?

Such a pre-processor could alert the user that one or more files are missing before generating the remaining files.
Cheers, Chris

[HansV]

I used a generic error handler for the following section as a whole:

Code: Select all

    strFile = Dir(strFolder & "*.doc*")
    Do While strFile <> ""
        Set objDoc = objWrd.Documents.Open(Filename:=strFolder & strFile)
        lngPos = InStrRev(strFile, ".")
        strPDF = Left(strFile, lngPos) & "pdf"
        objDoc.ExportAsFixedFormat OutputFileName:=strFolder & strPDF, ExportFormat:=17 ' wdExportFormatPDF
        objDoc.Close SaveChanges:=False
        strFile = Dir
    Loop

So whether a file cannot be opened, or cannot be saved as PDF. or any other problem occurs, the error handler will catch it.

[ChrisGreaves]

I used a generic error handler for the following section as a whole ... So whether a file cannot be opened, or cannot be saved as PDF. or any other problem occurs, the error handler will catch it.

Thanks, Chris