Insert complete photo dialog using code only

[ABabeNChrist]

I know how to insert a single photo or to use CTRL + A to select all the photos from photo dialog. But is there a way to do this with one piece of code.

[HansV]

Do you mean that you want to insert all pictures from a folder?

[ABabeNChrist]

yes from a selected folder

[HansV]

You'll have to modify the following code to suit your needs.

Code: Select all

Sub InsertPictures()
    Dim sFolder As String
    Dim sFile As String
    Dim i As Long
    Dim w As Worksheet
    With Application.FileDialog(4) ' msoFileDialogFolderPicker
        If .Show Then
            sFolder = .SelectedItems(1) & Application.PathSeparator
        Else
            Beep
            Exit Sub
        End If
    End With
    Set w = ActiveSheet ' or a specific sheet
    sFile = Dir(sFolder & "*.jpg")
    Do While sFile <> ""
        i = i + 1
        w.Shapes.AddPicture Filename:=sFolder & sFile, _
            LinktoFile:=False, SaveWithDocument:=True, _
            Left:=72 * i, Top:=72 * i, _
            Width:=400, Height:=300
        sFile = Dir
    Loop
End Sub

[ABabeNChrist]

Thank you Hans