Replacing text in MS Word with absolutely nothing

[geecee]

I have a Word document with about 100 names, each of which is separated by a comma and a blank space. What I wish to do is delete certain names, the comma and the blank space from the list and replace them with absolutely nothing. The following code does this but just one at a time, replacing the sample with the actual text. What I would like is to have the option to select up to a certain unknown number i.e until all I want to delete is selected. Hope thgis makes sense. Any help would be much appreciated. Thanks.

Code: Select all

Option Explicit
Sub replaceSampleToNothing()
    Dim sample
    sample = "sampleText"

    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = sample
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
End Sub

[HansV]

Do you want to replace several names with nothing? If so, you could use code like this (modify to suit your needs):

Code: Select all

Sub replaceSampleToNothing()
    Dim sample
    With ActiveDocument.Content.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
        For Each sample In Array("thisname, ", "thatname, ", "othername, ")
            .Execute FindText:=sample, ReplaceWith:="", Replace:=wdReplaceAll
        Next sample
    End With
End Sub

[geecee]

Thanks Hans. Perfect.