Prepend a word in table with "*"

[Robie]

Hi

I need to prepend "*" to the searched word in a table. If the word is found outside a table then this is ignored, i.e. no changes.
I am doing this as follows but is there a better way of doing it? It seems rather clumsy to me.

Code: Select all

Private Function PrependStar2String(Str As String)
    Dim selEnd As Long
    
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = Str
        .Replacement.Text = "*" + Str
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    While (Selection.Find.Execute)
        If (Selection.Information(wdWithInTable)) Then
            selEnd = Selection.Range.End
            Selection.Range.Text = "*" + Selection.Range.Text
            Selection.Start = selEnd + 1
        End If
    Wend
End Function

Thanks.
Robie

[HansV]

The code looks fine to me - I don't think there is a more efficient or elegant way to do it.

[Robie]

The code looks fine to me - I don't think there is a more efficient or elegant way to do it.

Thanks Hans.

[macropod]

IMHO, the following would be more efficient:

Code: Select all

Private Function PrependStar2String(Str As String)
With Selection.Range
    With .Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Text = Str
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
        .Execute
    End With
    Do While .Find.Found = True
        If .Information(wdWithInTable) Then .InsertBefore "*"
        .Collapse wdCollapseEnd
        .Find.Execute
    Loop
  End With
End Function

Note: If you're trying to search the whole document, change 'Selection' to 'ActiveDocument'. If you need to match the whole word, set '.MatchWholeWord = True' and, if it's case-sensitive, set '.MatchCase = True'

[HansV]

Thanks, Paul, that should be slightly more efficient.

[macropod]

FWIW, there's nothing in the original code or the code I posted that would cause it to stop execution when the end of the Selection is reached. As it stands, the code simply starts at the beginning of the Selection and continues executing until the end of the document is reached. Additional logic would be needed to make it stop when the end of the Selection is reached.

[Robie]

IMHO, the following would be more efficient:

Code: Select all

Private Function PrependStar2String(Str As String)
With Selection.Range
    With .Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Text = Str
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
        .Execute
    End With
    Do While .Find.Found = True
        If .Information(wdWithInTable) Then .InsertBefore "*"
        .Collapse wdCollapseEnd
        .Find.Execute
    Loop
  End With
End Function

Note: If you're trying to search the whole document, change 'Selection' to 'ActiveDocument'. If you need to match the whole word, set '.MatchWholeWord = True' and, if it's case-sensitive, set '.MatchCase = True'

Hi Paul

That works as expected. Thank you so much.