Autofit *all* tables to 'Autofit to Window'

[Robie]

Is there an easy way of doing this rather than going thru each table?

Also, is there a way to reset all Heading styles (Heading1 - Heading4) to 'indent from left' to -1.

Thanks.

[ChrisGreaves]

Is there an easy way of doing this rather than going thru each table?

Try the little macro "AutoFitContentAllTables" in the attached document.

[HansV]

This macro will loop through all tables in the active document:

Code: Select all

Sub AdjustAllTables()
  Dim tbl As Table
  For Each tbl In ActiveDocument.Tables
    tbl.AutoFitBehavior wdAutoFitWindow
  Next tbl
End Sub

[HansV]

And this one will set the left indent for Heading 1...4:

Code: Select all

Sub AdjustStyles()
  ActiveDocument.Styles(wdStyleHeading1).ParagraphFormat.LeftIndent = _
    Application.InchesToPoints(-1)
  ActiveDocument.Styles(wdStyleHeading2).ParagraphFormat.LeftIndent = _
    Application.InchesToPoints(-1)
  ActiveDocument.Styles(wdStyleHeading3).ParagraphFormat.LeftIndent = _
    Application.InchesToPoints(-1)
  ActiveDocument.Styles(wdStyleHeading4).ParagraphFormat.LeftIndent = _
    Application.InchesToPoints(-1)
End Sub

[Robie]

Wow. Thanks Chris and Hans. I thought it would reams and reams of VBA code. A big THANKS.

Sorry, one more question in relation to the paragraphs with heading styles. I have found that when I import these document into the current template all the headings are *lowercase*. It seems in their template the heading styles were set with 'ALL CAPS'. Now, is there a way to set up my Heading styles with *Initial letter as CAP*? For example '3. defects fixed in this release' would become '3. Defects fixed in this release'. I can see all options as part of the font settings but not this .

[HansV]

"First letter in upper case" is not a font, paragraph or style property. You could run this macro to "repair" the headings:

Code: Select all

Sub FixCaps()
  Dim par As Paragraph
  For Each par In ActiveDocument.Paragraphs
    Select Case par.Style
      Case ActiveDocument.Styles(wdStyleHeading1), _
          ActiveDocument.Styles(wdStyleHeading2), _
          ActiveDocument.Styles(wdStyleHeading3), _
          ActiveDocument.Styles(wdStyleHeading4)
        par.Range.Case = wdTitleSentence
    End Select
  Next par
End Sub